pkgname=nummi-git
pkgver=r42.ccc7ef1
pkgrel=1
pkgdesc="Web-based accounting interface"
arch=("any")
url="https://git.edgarpierre.fr/edpibu/nummi"
license=('AGPL3')
depends=(
	"gunicorn"
	"python-django"
)
makedepends=('git')
optdepends=("postgresql: database")
backup=("etc/${pkgname%-git}.env")
source=(
	"${pkgname}::git+ssh://gitea@git.edgarpierre.fr:39529/edpibu/nummi.git"
	"${pkgname%-git}.service"
	"${pkgname%-git}.tmpfiles"
	"${pkgname%-git}.sysusers"
	"${pkgname%-git}.nginx"
	"${pkgname%-git}.env"
)
md5sums=('SKIP'
         'd087cb0d37ba7570001affcfeab5b31c'
         '3c3caef26d924fb8f6bbce83743aaaac'
         '0210532a05e4b99593236524715063e2'
         '905cf1239a55c82a2fc60eceda71da6e'
         'ba911f184d52707732850cd7fb224849')

pkgver() {
	cd "$pkgname"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

package() {
	install -Dm644 ${pkgname%-git}.service -t "${pkgdir}"/usr/lib/systemd/system/
	install -Dm644 ${pkgname%-git}.tmpfiles "${pkgdir}"/usr/lib/tmpfiles.d/${pkgname%-git}.conf
	install -Dm644 ${pkgname%-git}.sysusers "${pkgdir}"/usr/lib/sysusers.d/${pkgname%-git}.conf
	install -Dm644 ${pkgname%-git}.nginx "${pkgdir}"/etc/nginx/sites-enabled/${pkgname%-git}.conf
	install -Dm750 ${pkgname%-git}.env -t "${pkgdir}"/etc/

	cd ${pkgname}/${pkgname%-git}
	find * -type f -exec install -Dm0644 "{}" "${pkgdir}/usr/share/webapps/${pkgname%-git}/{}" \;
}