From ea76c49bc99af5f186772d3c75ce3d49ddcc2550 Mon Sep 17 00:00:00 2001
From: "Edgar P. Burkhart" <git@edgarpierre.fr>
Date: Wed, 2 Feb 2022 22:20:31 +0100
Subject: [PATCH] Added single-file run

---
 run.dgibi | 164 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 164 insertions(+)
 create mode 100644 run.dgibi

diff --git a/run.dgibi b/run.dgibi
new file mode 100644
index 0000000..c058183
--- /dev/null
+++ b/run.dgibi
@@ -0,0 +1,164 @@
+OPTI 'DIME' 3 'ELEM' 'CU20';
+
+LX1p = 4.;
+LX1 = 20.;
+LY1 = 5.;
+LY1t = 3.;
+N1 = 5;
+
+LX0 = (LX1 * N1) + (LX1p * (N1+1));
+
+LX2 = 21.;
+LY2 = 10.;
+LY2t = 3.;
+N2 = N1;
+LX2p = (LX0 - (N2 * LX2)) / (N2 + 1);
+
+LX3 = 5.;
+LY3 = 2.;
+LY3t = 4.;
+N3 = N2 * 3;
+LX3p = (LX0 - (N3 * LX3)) / (N3 + 1);
+
+Y1 = LY1 + (LX1/2) + LY1t;
+Y2 = Y1 + LY2 + (LX2/2) + LY2t;
+Y3 = Y2 + LY3 + (LX3/2) + LY3t;
+
+DENSITE 1;
+
+P0 = (0.-LX1p) 0. 0.;
+PB = 0. 0. 0.;
+LI = D P0 PB;
+BL1 = D P0 PB;
+I = 0;
+REPETER BOUCLE1;
+	SI (I < N1);
+		PA = PB;
+		PB = (I * (LX1p+LX1)) LY1 0.;
+		LI = LI ET (D PA PB);
+
+		PA = PB;
+		PB = (I * (LX1p+LX1) + LX1) LY1 0.;
+		LI = LI ET (C PASS PA ((I * (LX1p+LX1) + (LX1/2)) (LY1+(LX1/2)) 0.) PB);
+
+		PA = PB;
+		PB = (I * (LX1p+LX1) + LX1) 0. 0.;
+		LI = LI ET (D PA PB);
+
+		PA = PB;
+		PB = (I * (LX1p+LX1) + LX1 + LX1p) 0. 0.;
+		LI = LI ET (D PA PB);
+		BL1 = BL1 ET (D PA PB);
+
+		I = I + 1;
+	SINON;
+		QUITTER BOUCLE1;
+	FINSI;
+FIN BOUCLE1;
+PA = PB;
+PB = (I * (LX1p+LX1)) (LY1 + (LX1/2)) 0.;
+LI = LI ET (D PA PB);
+
+PA = PB;
+PB = (I * (LX1p+LX1)) Y3 0.;
+LI = LI ET (D PA PB);
+
+PA = PB;
+PB = (0.-LX1p) Y3 0.;
+LI = LI ET (D PA PB);
+
+LI = LI ET (D PB P0);
+
+TR2 = LI;
+I = N2-1;
+REPETER BOUCLE2;
+	SI (I >EG 0);
+		PB = (I * (LX2p+LX2) + LX2p - LX1p) Y1 0.;
+		PA = (I * (LX2p+LX2) + LX2 + LX2p - LX1p) Y1 0.;
+		TRx = D PA PB;
+	
+		PA = PB;
+		PB = (I * (LX2p+LX2) + LX2p - LX1p) (Y1+LY2) 0.;
+		TRx = TRx ET (D PA PB);
+
+		PA = PB;
+		PB = (I * (LX2p+LX2) + LX2 + LX2p - LX1p) (Y1+LY2) 0.;
+		TRx = TRx ET (C PASS PA ((I * (LX2p+LX2) + (LX2/2) + LX2p - LX1p) (Y1+LY2+(LX2/2)) 0.) PB);
+
+		PA = PB;
+		PB = (I * (LX2p+LX2) + LX2 + LX2p - LX1p) Y1 0.;
+		TRx = TRx ET (D PA PB);
+
+		TR2 = TR2 ET TRx;
+		I = I - 1;
+	SINON;
+		QUITTER BOUCLE2;
+	FINSI;
+FIN BOUCLE2;
+
+I = N3-1;
+REPETER BOUCLE3;
+	SI (I >EG 0);
+		PB = (I * (LX3p+LX3) - LX1p + LX3p) Y2 0.;
+		PA = (I * (LX3p+LX3) + LX3 - LX1p + LX3p) Y2 0.;
+		TRx = D PA PB;
+	
+		PA = PB;
+		PB = (I * (LX3p+LX3) - LX1p + LX3p) (Y2+LY3) 0.;
+		TRx = TRx ET (D PA PB);
+
+		PA = PB;
+		PB = (I * (LX3p+LX3) + LX3 - LX1p + LX3p) (Y2+LY3) 0.;
+		TRx = TRx ET (C PASS PA ((I * (LX3p+LX3) + (LX3/2) - LX1p + LX3p) (Y2+LY3+(LX3/2)) 0.) PB);
+
+		PA = PB;
+		PB = (I * (LX3p+LX3) + LX3 - LX1p + LX3p) Y2 0.;
+		TRx = TRx ET (D PA PB);
+
+		TR2 = TR2 ET TRx;
+		I = I - 1;
+	SINON;
+		QUITTER BOUCLE3;
+	FINSI;
+FIN BOUCLE3;
+
+ELIM TR2 .1;
+TRAC TR2;
+
+SU = SURF 'PLAN' TR2;
+ELIM SU .01;
+TRAC SU;
+
+VO = SU VOLU 6 'TRAN' (0. 0. 4.) ;
+TRAC VO;
+
+
+* TRAC SU;
+
+* OPTI 'MODE' 'PLAN' 'DEFO';
+OPTI 'DIME' 3 'ELEM' 'CU20';
+
+EP0 = 4.;
+
+MOM = MODE VO 'MECANIQUE' 'ELASTIQUE';
+MAM = MATERIAL MOM YOUN 2.4E11 NU 0.2 RHO 2700.;
+CL1 = BLOQ DEPLA ROTA BL1;
+
+RIG1 = RIGI MOM MAM;
+RIG1 = RIG1 ET CL1;
+
+MAS1 = MASS MOM MAM;
+
+
+TAB1 = VIBR PROCHE (PROG 1.) ( ENTI (PROG 10) ) RIG1 MAS1;
+
+LIST TAB1;
+
+
+REPETER POUR ((DIME (TAB1 . MODES)) - 2);
+	LIST &POUR;
+	LIST TAB1 . MODES . (&POUR);
+	DEF = DEFO VO TAB1 . MODES . (&POUR) . DEFORMEE_MODALE 10. 'ROUG';
+	TR = TRAC DEF 'FACE';
+FIN POUR;
+FIN;