nummi/PKGBUILD

pkgname=nummi-git
pkgver=r151.ee26d0d
pkgrel=1
pkgdesc="Web-based accounting interface"
arch=("any")
url="https://git.edgarpierre.fr/edpibu/nummi"
license=('AGPL3')
depends=(
	"gunicorn"
	"python-django"
	"python-matplotlib"
	"python-toml"
)
makedepends=("git")
optdepends=("postgresql: database")
backup=("etc/${pkgname%-git}.env")
source=(
	"${pkgname}::git+https://git.edgarpierre.fr/edpibu/nummi"
	"${pkgname%-git}.service"
	"${pkgname%-git}.tmpfiles"
	"${pkgname%-git}.sysusers"
	"${pkgname%-git}.nginx"
	"config.toml"
)
b2sums=('SKIP'
        '9e9b62a141bb4594dc203978d5c56dd397ed6c095e6f83fdea07ded2fa46dd2e052aa8f80729a3b612e3773aa487660fcca791079ad4885b825c9c831df61b45'
        'cd42e864d82ca5ea191d2c15cec55afea272a875f19ebc1252e03fb86ef3d62820e2fedd706a8da0b0e3a7aee355e0bb5dcdb7f3bd803497c1320fab540f7d70'
        '78bebc6cca3f8b520783565de9122cc57e62eb629d3693dfaa322a77f4be3c55c5cd5a460bd1f6f3028f4dd1b2018ec6166b7f9aaf55ac3be6178bd1a3a00405'
        'c878c463ecb58d94b3f9b96d798b098a7718aec6df4b424a60674c0a9daf9abcb4556e527e55f67dbb093e109145b0ca17556f7dce66116ba7b170ead61acc16'
        '5bdc097ab3fa7e8e128d194bfb6c0fefb5528903e2b8765557a82033f8925c1174dbe73007a595e32c5e415cf6f19957c35bbe463c50d2813894c20c8a28a88d')

pkgver() {
	cd "$pkgname"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

package() {
	install -Dm644 ${pkgname%-git}.service -t "${pkgdir}"/usr/lib/systemd/system/
	install -Dm644 ${pkgname%-git}.tmpfiles "${pkgdir}"/usr/lib/tmpfiles.d/${pkgname%-git}.conf
	install -Dm644 ${pkgname%-git}.sysusers "${pkgdir}"/usr/lib/sysusers.d/${pkgname%-git}.conf
	install -Dm644 ${pkgname%-git}.nginx "${pkgdir}"/etc/nginx/sites-enabled/${pkgname%-git}.conf
	install -Dm750 config.toml -t "${pkgdir}"/etc/${pkgname%-git}/

	cd ${pkgname}/${pkgname%-git}
	find * -type f -exec install -Dm0644 "{}" "${pkgdir}/usr/share/webapps/${pkgname%-git}/{}" \;
}