nummi/pkgbuild/PKGBUILD

pkgname=nummi
pkgver=v0.9.1
pkgrel=1
pkgdesc="Web-based accounting interface"
arch=("any")
url="https://git.edgarpierre.fr/edpibu/nummi"
license=('AGPL3')
depends=(
	"gunicorn"
	"python-django"
	"python-toml"
	"python-psycopg"
)
makedepends=("git")
optdepends=("postgresql: database")
backup=("etc/${pkgname}/config.toml")
_tag=bd6447606b8fb6a8f5006ef504f73618b179f9ac
source=(
	"${pkgname}::git+https://git.edgarpierre.fr/edpibu/nummi?signed#tag=$_tag"
	"${pkgname}.service"
	"${pkgname}.tmpfiles"
	"${pkgname}.sysusers"
	"${pkgname}.nginx"
	"config.toml"
)
b2sums=('SKIP'
        'c1e81c04cb09bf03e6f1f06b1de1a28bf39bf2b1571819071fe95e214847c7712e11ec9988061284fda2a3f565262018ac733603034c4c4aa98a50bc42f6bd95'
        'cd42e864d82ca5ea191d2c15cec55afea272a875f19ebc1252e03fb86ef3d62820e2fedd706a8da0b0e3a7aee355e0bb5dcdb7f3bd803497c1320fab540f7d70'
        '78bebc6cca3f8b520783565de9122cc57e62eb629d3693dfaa322a77f4be3c55c5cd5a460bd1f6f3028f4dd1b2018ec6166b7f9aaf55ac3be6178bd1a3a00405'
        'c878c463ecb58d94b3f9b96d798b098a7718aec6df4b424a60674c0a9daf9abcb4556e527e55f67dbb093e109145b0ca17556f7dce66116ba7b170ead61acc16'
        'efe7c0a7da971bbd43675c71bc16bd3d44948cec55fb5c2237196ad52d712f3e958790f171f0fab82e9ea5529a60789685c5936489b4e2ffdb4a0e1b3fcb031c')

pkgver() {
	cd "$pkgname"
	git describe
}

package() {
	install -Dm644 ${pkgname}.service -t "${pkgdir}"/usr/lib/systemd/system/
	install -Dm644 ${pkgname}.tmpfiles "${pkgdir}"/usr/lib/tmpfiles.d/${pkgname}.conf
	install -Dm644 ${pkgname}.sysusers "${pkgdir}"/usr/lib/sysusers.d/${pkgname}.conf
	install -Dm644 ${pkgname}.nginx "${pkgdir}"/etc/nginx/sites-enabled/${pkgname}.conf
	install -Dm600 -o nummi -g nummi config.toml -t "${pkgdir}"/etc/${pkgname}/

	cd ${pkgname}/${pkgname}
	find * -type f -exec install -Dm0644 "{}" "${pkgdir}/usr/share/webapps/${pkgname}/{}" \;
}